//ngg
!母艦設計=「母艦の可視はオフ」
!APPタイトル=「ngg1」
!BGM=「m2.mp3」
!MOVE=「poko.wav」
!イベントデータ=「ivent.csv」
!バックデータ=「ngg_bg1.png」
!chr1=「ngg_chr1.png」
!obj1=「ngg_obj1.png」

MC=0
RC=0
メッセージスタック=「」
リザルトスタック=「」
クリックスイッチ=0
ページポインタ=1
進行スイッチ=0

p位置=0
m位置=0
p体力=0
m体力=0
pフラグ[0]=0

母艦について
	タイトルはAPPタイトル
	スタイルは「枠固定」//枠なし」
	クライアントHは202
	クライアントWは402
	0へ最大化ボタン有効変更
	背景色は黒色
	終了可能は0

メインとはパネル
メインについて
	レイアウトは「全体」
	スタイルは「凹」
	背景色は黒色

ステージとはフォーム
ステージについて
	親部品はメイン
	レイアウトは「上」
	スタイルは「枠なし」
	背景色は黒色
	Hは115
	
ソデとはフォーム
ソデについて
	親部品はメイン
	レイアウトは「全体」
	スタイルは「枠なし」
	テキストは「コントロール」
	背景色は黒色
	
トークとはフォーム
トークについて
	親部品はメイン
	レイアウトは「全体」
	スタイルは「枠なし」
	背景色は黒色

コントロールとはパネル
コントロールについて
	親部品はソデ
	スタイルは「枠なし」
	背景色は黒色
	Wは100
	Hは20


探索とはボタン//ラベル
探索について
	親部品はコントロール
	テキストは「!」
	レイアウトは「全体」
	文字サイズは12
	
進行とはボタン//ラベル
進行について
	親部品はコントロール
	テキストは「<<」
	レイアウトは「左」
	文字サイズは12
	Wは30
	
退却とはボタン//ラベル
退却について
	親部品はコントロール
	テキストは「>>」
	レイアウトは「右」
	文字サイズは12
	Wは30
	
リザルトとはラベル
リザルトについて
	親部品はソデ
	レイアウトは「上」
	テキストは「」
	文字色は白色
	文字位置は「中央」

メッセージとはラベル
メッセージについて
	親部品はトーク
	レイアウトは「全体」
	テキストは「{~}」
	文字色は白色
	文字位置は「左」
	
ステータスとはラベル
ステータスについて
	親部品はステージ
	レイアウトは「上」
	テキストは「{APPタイトル}」
	文字色は白色
	文字位置は「中央」
	文字書体は「ＭＳ　Ｐゴシック|25|太字」
	Hは50
	
//キャラ登録
キャラ１とはイメージ
キャラ１について
	親部品はステージ
	Yは65//固定
	Xは295
	可視はオフ

//オブジェクト登録
オブジェ１とはイメージ
オブジェ１について
	親部品はステージ
	Yは65//固定
	Xは155
	可視はオフ

//ivent----------------------------------------------------------

母艦の閉じた時は
	「music」をMコン
	母艦の終了可能は1
	終わる

母艦のキー押した時は
	もしトークの可視がオンならば
		クリックスイッチ=1
	
メッセージのクリックした時は
	クリックスイッチ=1

進行のクリックした時は
	「move」を0で「シーク」とMコン
	「move」を「」で「再生」とMコン
	p位置=p位置+1
	p体力=p体力-1
	部屋処理
	
退却のクリックした時は
	「move」を0で「シーク」とMコン
	「move」を「」で「再生」とMコン
	p位置=p位置-1
	p体力=p体力-1
	部屋処理

ソデのサイズ変更した時は
	コントロールのXは((ソデのW-コントロールのW)/2)
	コントロールのYは((ソデのH-コントロールのH)/2)+7

//main-----------------------------------------------------------	
母艦を中央移動
母艦の可視はオン
イベントポインタ=0
母艦再描画
0.1秒待つ

BGMロード
データロード
ゲーム初期化
部屋処理

1の間
	0.08秒待つ
	標準ルーチン
	MC=MCでメッセ表示
	RC=RCでリザルト表示

●データロード
	ステージの画像はバックデータ
	キャラ１の画像はchr1
	オブジェ１の画像はobj1
	ステージの可視はオン
	ソデの可視はオン
	キャラ１の可視はオン
	
●BGMロード
	「music」を「{BGM}」で「開く」とMコン
	「move」を「{MOVE}」で「開く」とMコン

●部屋処理
	ソデの可視はオフ
	RC=0
	p位置で条件分岐
		0ならば
			進行スイッチ=1
			リザルトスタック=「」
			リザルト=「」
			退却の有効はオフ
			
		1ならば
			もしpフラグ[0]が0ならば
				pフラグ[0]=1
				「music」を「repeat」で「再生」とMコン
				
			リザルトスタック=「@天井の裂け目から月の光が差し込んでいます。\」を文字列分解
			退却の有効はオン
			進行スイッチ=1
			
		3ならば
			リザルトスタック=「@大きな石像があります\」を文字列分解
			進行スイッチ=1
			
		5ならば
			もしpフラグ[2]が0ならば
				リザルトスタック=「@行き止まりです\」を文字列分解
				進行の有効はオフ
			違えば
				リザルトスタック=「@壁が崩れています\」を文字列分解
				
			進行スイッチ=1
			
			
		違えば
			進行スイッチ=1
			リザルト=「」
			リザルトスタック=「」
			退却の有効はオン
			進行の有効はオン
			探索の有効はオン

●標準ルーチン
	もしp体力>0ならば
		ステータスのテキストは「{p位置}/{m位置}{~}{p体力}/{m体力}」
		もし進行スイッチ=1ならば
			進行スイッチ=0
			ソデの可視はオン
	違えば
		ゲームオーバー


●ゲームオーバー
	キャラ１の可視はオフ
	「music」を「0」で「停止」とMコン
	ステータスのテキストは「{p位置}/{m位置}{~}{p体力}/{m体力}{~}GameOver」
	メッセージスタック=「@突然、あなたの意識が遠くなっていく。@あなたは自分が思っていたよりも、疲れていたようだ。@少し眠ろう...」を文字列分解
		
●ゲーム初期化
	p位置=0
	m位置=256
	p体力=100
	m体力=100
	
	128回
		pフラグ[回数-1]=0

	「music」を0で「シーク」とMコン
	ステージの可視はオン
	ソデの可視はオン
	キャラ１の可視はオン


●メッセ表示(Cで)
	もしメッセージスタック[0]が「」でなければ
		もし(C==0)ならば
			メッセージ=「」
			トークの可視はオン
			
		もしクリックスイッチが1ならば
			クリックスイッチ=0
			メッセージスタックを反復
				C=Cでメッセージ出力
		違えば
			C=Cでメッセージ出力
	違えば
		もしクリックスイッチが1ならば
			クリックスイッチ=0
			トークの可視はオフ
			進行スイッチ=1
			C=0
	Cを戻す
	
●メッセージ出力(Cで)
	もし((メッセージスタック[0]!=「」)&&(C<1024))ならば
		メッセージスタック[C]で条件分岐
			「@」ならば
				メッセージ=メッセージ&「{~}　」
			「\」ならば
				メッセージスタック[0]=「」
				C=-1
			違えば
				メッセージ=メッセージ&メッセージスタック[C]
		
		C+1を戻す
	違えば
		Cを戻す
	

●リザルト表示(Cで)
	もし((リザルトスタック[0]!=「」)&&(MC==0))ならば
		もし(C==0)ならば
			リザルト=「」
			
		C=Cでリザルト出力
	違えば
		C=0
	Cを戻す
	
●リザルト出力(Cで)
	もし((リザルトスタック[0]!=「」)&&(C<1024))ならば
		リザルトスタック[C]で条件分岐
			「@」ならば
				リザルト=リザルト&「{~}」
			「\」ならば
				リザルトスタック[0]=「」
				C=-1
			違えば
				リザルト=リザルト&リザルトスタック[C]
		
		C+1を戻す
	違えば
		Cを戻す
		

/*-------------------------------------------------------------
関数：Mコン
	Conは制御、Exは制御オプション、Obは対象をあらわす
	Sコマンド表
	「開く」:open(ObをExで開く)
	「再生」:play(ObをExで再生)
	「停止」:pause(Obを一時停止)
	「シーク」:Seek(ObをExでシーク)
	
	_:close
	
	ex「開く」: 「music」を「{BGM}」で「開く」とMコン
	ex「再生」: 「music」を「repeat」で「再生」とMコン
	ex「停止」: 「music」を「0」で「停止」とMコン
	ex「シーク」: 「music」を「10」で「シーク」とMコン
	ex_: 「music」をMコン
---------------------------------------------------------------*/
●Mコン(Obを{参照渡し=「」}Exで{文字列=「」}Conと)
/*
	mconSとは文字列=1
	エラー監視
		Conで条件分岐
			「開く」ならば
				「{Ex}」が存在
				もしそれがはいならば
					「open "{Ex[0]}" alias {Ob} type mpegvideo {Ex[1]}」をMCI送信
					「set {Ob} time format milliseconds」をMCI送信
					mconS=「status {Ob} length」をMCI送信
				違えば
					mconS=-1
					
			「位置情報フォーマット」ならば
				「set {Ob} time format {Ex}」をMCI送信//milliseconds
				mconS=「status {Ob} length」をMCI送信
				
			「再生」ならば
				"play {Ob} {Ex}"をMCI送信
			「停止」ならば
				"pause {Ob}"をMCI送信
			「シーク」ならば
				"seek {Ob} to {Ex}"をMCI送信
		
			「位置取得」ならば
				mconS="status {Ob} position"をMCI送信
				
			「ウィンドウ設定」ならば
				"window {Ob} handle {Ex}"をMCI送信
			「サイズ設定」ならば
				"put {Ob} destination at {Ex[0]} {EX[1]} {Ex[2]} {Ex[3]}"をMCI送信
				
			「ボリューム設定」ならば
				"setaudio {Ob} volume to {Ex}"をMCI送信
			「速度設定」ならば
				"set {Ob} speed {Ex}"をMCI送信
				
			違えば
				"close {Ob}"をMCI送信
				
	エラーならば
		mconS=-1//「{エラーメッセージ}」
	
	mconSを戻す
*/