//ネットワークイメージクローラーv0.1
//!母艦設計=「母艦の可視はオフ」
# 初期設定
アプリタイトルは「にっく ver0.1」。

エンジンは「
googleImageSerch,http://images.google.com/images?,1
google(jp)イメージ検索,http://images.google.co.jp/images?,1
」

//title,GoogleAPIset ver20051214
//アプリ内検索語句,送信対象変数(サーバーサイド),代入できる値
設定項目@1は『
イメージ,q,@word,検索語句です。必ず指定
サイト,as_sitesearch,@url,,ターゲットとするURLを指定できます。
表示開始位置,start,@no,,表示を開始する位置を指定できます。

色種類,imgc,@color,mono|color|gray,画像タイプに関する設定です。
タイプ,as_filetype,@filetype,jpg|gif|png,ファイルタイプに関する設定です。
サイズ,imgsz,@imgsize,icon|small|medium|large|xlarge|xxlarge,サイズ指定です
サーバ,svnum,@sv1|2|3|4|5|6|7|8|9|10,サーバー指定？未確認
類似フィルタ,filter,@fil,0|1
アダルトフィルタ,safe,@ad,off|on

言語,hl,ja,ja
文字コード,ie,Shift_JIS,Shift_JIS
』

動作キー@1=『google,btnG=Google+%E6%A4%9C%E7%B4%A2,意味は知りません。あったほうが早いような気がしたりそうでもないような気も』

マッチ式@1=『/images?q=tbn:*:(*)』

一括受信数@1=20

受信可能リスト=『
image/jpeg
image/png
image/gif
image/pjpeg
image/x-png
text/html
』
atWord=『』
atUrl=『』
atCom=『』
EDB=『』
serchReq=『』
Head=『』
Max=0
対象文字=『』
対象サイト=『』
リンクデータ=『』
E選択値=1
経過ダイアログ=0

「
,sys,アプリケーション
sys,mr,RUN,,,テスト動作
sys,mc,Clear,,,クリア動作」をメニュー一括作成

母艦はアプリタイトル

ヘッドステージとはパネル
そのレイアウトは上
そのスタイルは「枠なし」
そのHは40

スペーサーステージ1とはパネル
その親部品はヘッドステージ
そのレイアウトは上
そのスタイルは「枠なし」
そのHは10

検索ステージとはパネル
その親部品はヘッドステージ
そのレイアウトは上
そのスタイルは「枠なし」
そのHは20

スペーサーステージ2とはパネル
その親部品はヘッドステージ
そのレイアウトは上
そのスタイルは「枠なし」
そのHは10

説明ラベル1とはラベル
その親部品は検索ステージ
そのレイアウトは左
そのテキストは「 Word : 」

実行ボタンとはボタン
その親部品は検索ステージ
そのレイアウトは右
そのテキストは「検索」
実行ボタンのクリックした時は〜
	テスト動作

検索語句エリアとはエディタ
その親部品は検索ステージ
そのレイアウトは全体

メモ1とはTエディタ
そのレイアウトは全体
そのHTMLにカラーリング設定
メモ1のダブルクリックした時は〜
	メモ1のダブルクリック単語選択

現在経過とはステータスバー
現在データ表示
待機

●テスト動作
	mrの有効はオフ
	検索語句エリアの有効はオフ
	実行ボタンの有効はオフ
	/*
	「検索語句を教えてください」で尋ねる
	対象文字=それ
	*/
	対象文字=検索語句エリア
	
	//対象文字と言う
	メイン
	
	現在データ表示
	mrの有効はオン
	検索語句エリアの有効はオン
	実行ボタンの有効はオン
●クリア動作
	リンクデータ=「」
	現在データ表示
	
●現在データ表示
	メモ1=「{エンジン[E選択値][0]}
{対象文字}{\n}Image x {Max}{\n}{serchReq}{\n}{\n}
Result:{\n}{リンクデータ}」
//{Head}{\n}{Data}{\n}
●メイン
	画像カウント=980
	
	現在経過=「データ受信中」
	
	アクセスURL処理
	「表示開始位置」のエンジンコマンド取得
	serchReq=「{serchReq}&{atCom}={画像カウント}」
	
	exe_sw=1
	serchReqの「」でヘッダチェック//念のためチェック
	もし、exe_sw=1ならば、
		0秒待つ
		Data=serchReqからHTTPデータ取得
		Max=Dataの総枚数取得
		
	現在経過=「RUN?」
	画像カウント=0
	アクセスURL処理
	「全部で{Max}枚のデータが存在。{\n}実行しますか？」と二択
	もしそれがはいならば、
		(画像カウント<Max+20)の間
			現在経過=「URLデータ受信中　{画像カウント} / {Max}」
			「表示開始位置」のエンジンコマンド取得
			serchReq2=「{serchReq}&{atCom}={画像カウント}」
			Data=serchReq2からHTTPデータ取得
			
			リンクデータ=「{リンクデータ}{\n}{Dataのイメージアドレス抽出}」
			メモ1=リンクデータ
			
			画像カウント=画像カウント+一括受信数@(エンジン[E選択値][2])
			0秒待つ
		ここまで
		
		画像カウント=0
		リンクデータを反復
			画像カウント=画像カウント+1
		画像カウント=画像カウント-1
		現在経過=「URLデータ受信完了　総枚数：{画像カウント}」
	
	

●イメージアドレス抽出(ページデータの)
	元イメージアドレス=『』
	ページデータからHTMLリンク抽出して反復
		もしそれが「{マッチ式@(エンジン[E選択値][2])}」に一致＝1ならば
			「{抽出文字列[0]}」の「{\n}」を「」へ置換
			それを元イメージアドレスに配列追加
	それは元イメージアドレス

●アクセスURL処理
	atWordは対象文字をURLエンコード
	atUrlは対象サイトをURLエンコード
	
	「イメージ」のエンジンコマンド取得
	serchReq=「{エンジン[E選択値][1]}{atCom}={atWord}」
	
	「言語」のエンジンコマンド取得
	serchReq=「{serchReq}&{atCom}={atPts}」
	
	/*
	*/
	「文字コード」のエンジンコマンド取得
	serchReq=「{serchReq}&{atCom}={atPts}」
	//動作キー付与
	Key=動作キー@(エンジン[E選択値][2])
	Key2=Key[0][1]
	//serchReq=「{serchReq}&{Key2}」
	//serchReqと言う
	
	
●総枚数取得(解析対象の)
	Max=0
	解析対象の「検索結果 約 <b>」から「</b> 件中 <b>」まで範囲切り取る
	もしそれが「」でなければ、
		MaxはINT（それの「,」を「」に置換）
	Maxを戻す
	
●エンジンコマンド取得(検索対象の)
	EDB=設定項目@(エンジン[E選択値][2])
	EDBを反復
		もし、それ[0][0]が「{検索対象}」ならば、
			atCom=それ[0][1]
			atPts=それ[0][2]
		0秒待つ
	ここまで

●ヘッダチェック(取得対象の取得拡張子で)
	exe_sw=0
	Head=取得対象からHTTPヘッダ取得
	Head2=Headの「: 」を「,」へ置換
	Head2を反復
		もし、それ[0][0]が「Content-Type」ならば、
			exe_sw=受信可能リストをそれ[0][1]でリストマッチ
		0秒待つ
	ここまで

●リストマッチ({参照渡し}検査対象を検査語句で)
	match_sw=0
	検査対象を反復
		もし、それが「{検査語句}」ならば、
			match_sw=1
		0秒待つ
	ここまで
	それ=0
	もしmatch_swが1ならば、
		それ=1
		/*
●リストHTTP取得({参照渡し}取得リストの)
	*/